openide/python/educational-core/build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

buildscript {
  ext.kotlin_version = '1.0.2'
  repositories {
    mavenCentral()
  }
  dependencies {
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
  }
}

plugins {
  id "org.jetbrains.intellij" version "0.0.43"
}

subprojects {

  apply plugin: 'java'
  apply plugin: 'kotlin'
  apply plugin: "org.jetbrains.intellij"

  tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }

  sourceSets {
    main {
      java.srcDir 'src'
      kotlin.srcDirs 'src'
      resources.srcDir 'resources'
    }
    test {
      java.srcDir 'test'
    }
  }

  intellij {
    version ideaVersion
    updateSinceUntilBuild Boolean.valueOf(updateBuildNumber)
    downloadSources Boolean.valueOf(downloadIdeaSources)
    sandboxDirectory = new File(rootProject.projectDir, "gradleBuild/idea-sandbox")
  }

  processResources {
    filesNotMatching("**/*.png") {
      it.filter(ReplaceTokens, tokens: [
        'VERSION'     : version.toString(),
        'BUILD-NUMBER': buildNumber,
      ])
    }
  }

  afterEvaluate {
    tasks.getByName('buildPlugin') {
      archiveName = "$intellij.pluginName-$version-${buildNumber}.zip"
    }
  }

  buildDir = new File(rootProject.projectDir, "gradleBuild/" + project.name)
}

project(':student') {

  dependencies {
    compile fileTree(dir: 'lib', include: ['*.jar'])
  }

  intellij {
    pluginName 'student'
  }

}

project(':course-creator') {

  dependencies {
    compile project(':student')
  }

  intellij {
    pluginName 'course-creator'
  }

}