add cmake install targets

.vscode/settings.json

@@ -5,6 +5,18 @@
         "files.trimFinalNewlines": true,
         "files.trimTrailingWhitespace": true
     },
+    "[cmake]": {
+        "files.encoding": "utf8",
+        "files.insertFinalNewline": true,
+        "files.trimFinalNewlines": true,
+        "files.trimTrailingWhitespace": true
+    },
+    "[python]": {
+        "files.encoding": "utf8",
+        "files.insertFinalNewline": true,
+        "files.trimFinalNewlines": true,
+        "files.trimTrailingWhitespace": true
+    },
     "clangd.arguments": [
         "--all-scopes-completion",
         "--background-index",

CMakeLists.txt

@@ -1,37 +1,96 @@
-cmake_minimum_required(VERSION 3.15 FATAL_ERROR)
+cmake_minimum_required(VERSION 3.21 FATAL_ERROR)
 
-if(NOT DEFINED PROJECT_NAME)
+project(vmath.hpp
-    set(BUILD_AS_STANDALONE ON)
+    VERSION "0.0.1"
-else()
+    DESCRIPTION "C++17 tiny vector math library"
-    set(BUILD_AS_STANDALONE OFF)
+    HOMEPAGE_URL "https://github.com/blackmatov/vmath.hpp")
-endif()
 
-project(vmath.hpp)
+#
+# LIBRARY
+#
 
 add_library(${PROJECT_NAME} INTERFACE)
-target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_17)
+add_library(vmath.hpp::vmath.hpp ALIAS ${PROJECT_NAME})
-target_include_directories(${PROJECT_NAME} INTERFACE headers)
+
+target_compile_features(${PROJECT_NAME} INTERFACE
+    cxx_std_17)
+
+target_include_directories(${PROJECT_NAME} INTERFACE
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/headers>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
 
 #
-# BUILD_AS_STANDALONE
+# INSTALL
 #
 
-if(NOT ${BUILD_AS_STANDALONE})
+if(PROJECT_IS_TOP_LEVEL)
-    return()
+    include(CMakePackageConfigHelpers)
+    include(GNUInstallDirs)
+
+    set(VMATH_HPP_INSTALL_CONFIG_DIR
+        "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}")
+
+    set(VMATH_HPP_INSTALL_CONFIG_INPUT
+        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Config.cmake.in")
+
+    set(VMATH_HPP_INSTALL_GENERATED_CONFIG_CMAKE
+        "${CMAKE_CURRENT_BINARY_DIR}/generated/${PROJECT_NAME}-config.cmake")
+
+    set(VMATH_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE
+        "${CMAKE_CURRENT_BINARY_DIR}/generated/${PROJECT_NAME}-config-version.cmake")
+
+    configure_package_config_file(
+        "${VMATH_HPP_INSTALL_CONFIG_INPUT}"
+        "${VMATH_HPP_INSTALL_GENERATED_CONFIG_CMAKE}"
+        INSTALL_DESTINATION "${VMATH_HPP_INSTALL_CONFIG_DIR}"
+        NO_SET_AND_CHECK_MACRO
+        NO_CHECK_REQUIRED_COMPONENTS_MACRO)
+
+    write_basic_package_version_file(
+        "${VMATH_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE}"
+        VERSION ${PROJECT_VERSION}
+        COMPATIBILITY AnyNewerVersion
+        ARCH_INDEPENDENT)
+
+    install(
+        TARGETS ${PROJECT_NAME}
+        EXPORT ${PROJECT_NAME}-targets
+        INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+
+    install(
+        DIRECTORY headers/${PROJECT_NAME}
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+
+    install(
+        EXPORT ${PROJECT_NAME}-targets
+        FILE ${PROJECT_NAME}-targets.cmake
+        NAMESPACE ${PROJECT_NAME}::
+        DESTINATION "${VMATH_HPP_INSTALL_CONFIG_DIR}")
+
+    install(
+        FILES "${VMATH_HPP_INSTALL_GENERATED_CONFIG_CMAKE}"
+              "${VMATH_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE}"
+        DESTINATION "${VMATH_HPP_INSTALL_CONFIG_DIR}")
 endif()
 
-option(BUILD_WITH_COVERAGE "Build with coverage" OFF)
+#
-option(BUILD_WITH_SANITIZERS "Build with sanitizers" OFF)
+# DEVELOPER
+#
 
-enable_testing()
+if(PROJECT_IS_TOP_LEVEL)
-set_property(GLOBAL PROPERTY USE_FOLDERS ON)
+    option(BUILD_WITH_COVERAGE "Build with coverage" OFF)
-set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMake")
+    option(BUILD_WITH_SANITIZERS "Build with sanitizers" OFF)
-list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
 
-include(EnableASan)
+    enable_testing()
-include(EnableGCov)
+    set_property(GLOBAL PROPERTY USE_FOLDERS ON)
-include(EnableUBSan)
+    set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMake")
+    list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
 
-add_subdirectory(singles)
+    include(EnableASan)
-add_subdirectory(vendors)
+    include(EnableGCov)
-add_subdirectory(untests)
+    include(EnableUBSan)
+
+    add_subdirectory(singles)
+    add_subdirectory(vendors)
+    add_subdirectory(untests)
+endif()

CMakePresets.json

@@ -3,7 +3,7 @@
 
     "cmakeMinimumRequired": {
         "major": 3,
-        "minor": 20,
+        "minor": 21,
         "patch": 0
     },
 

README.md

@@ -41,7 +41,7 @@ Also, you can add the root repository directory to your [cmake](https://cmake.or
 
 ```cmake
 add_subdirectory(external/vmath.hpp)
-target_link_libraries(your_project_target PUBLIC vmath.hpp)
+target_link_libraries(your_project_target PUBLIC vmath.hpp::vmath.hpp)
 ```
 
 ## Disclaimer

cmake/Config.cmake.in

@@ -0,0 +1,3 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/vmath.hpp-targets.cmake")

cmake/EnableASan.cmake

@@ -1,14 +1,15 @@
 # https://clang.llvm.org/docs/AddressSanitizer.html
 
-add_library(enable_asan INTERFACE)
+add_library(${PROJECT_NAME}.enable_asan INTERFACE)
+add_library(${PROJECT_NAME}::enable_asan ALIAS ${PROJECT_NAME}.enable_asan)
 
-target_compile_options(enable_asan INTERFACE
+target_compile_options(${PROJECT_NAME}.enable_asan INTERFACE
     -fsanitize=address
     -fno-omit-frame-pointer
     -fsanitize-address-use-after-scope
     -fsanitize-address-use-after-return=always)
 
-target_link_options(enable_asan INTERFACE
+target_link_options(${PROJECT_NAME}.enable_asan INTERFACE
     -fsanitize=address
     -fno-omit-frame-pointer
     -fsanitize-address-use-after-scope

cmake/EnableGCov.cmake

@@ -1,9 +1,10 @@
 # https://clang.llvm.org/docs/SourceBasedCodeCoverage.html
 
-add_library(enable_gcov INTERFACE)
+add_library(${PROJECT_NAME}.enable_gcov INTERFACE)
+add_library(${PROJECT_NAME}::enable_gcov ALIAS ${PROJECT_NAME}.enable_gcov)
 
-target_compile_options(enable_gcov INTERFACE
+target_compile_options(${PROJECT_NAME}.enable_gcov INTERFACE
     --coverage)
 
-target_link_options(enable_gcov INTERFACE
+target_link_options(${PROJECT_NAME}.enable_gcov INTERFACE
     --coverage)

cmake/EnableUBSan.cmake

@@ -1,11 +1,12 @@
 # https://clang.llvm.org/docs/UndefinedBehaviorSanitizer.html
 
-add_library(enable_ubsan INTERFACE)
+add_library(${PROJECT_NAME}.enable_ubsan INTERFACE)
+add_library(${PROJECT_NAME}::enable_ubsan ALIAS ${PROJECT_NAME}.enable_ubsan)
 
-target_compile_options(enable_ubsan INTERFACE
+target_compile_options(${PROJECT_NAME}.enable_ubsan INTERFACE
     -fsanitize=undefined
     -fno-omit-frame-pointer)
 
-target_link_options(enable_ubsan INTERFACE
+target_link_options(${PROJECT_NAME}.enable_ubsan INTERFACE
     -fsanitize=undefined
     -fno-omit-frame-pointer)

singles/CMakeLists.txt

@@ -24,6 +24,8 @@ add_custom_target(${PROJECT_NAME}.generate
 #
 
 add_library(${PROJECT_NAME} INTERFACE)
+add_library(vmath.hpp::singles ALIAS ${PROJECT_NAME})
+
 add_dependencies(${PROJECT_NAME} ${PROJECT_NAME}.generate)
 target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_17)
 target_include_directories(${PROJECT_NAME} INTERFACE headers)

singles/scripts/build_singles.py

@@ -34,7 +34,7 @@ def CollectSystemIncludes(headerPath, parsedHeaders = set()):
             return set()
 
         headerIncludes = set()
-        
+
         parsedHeaders.add(headerPath)
         headerLines = headerContent.split('\n')
 
@@ -56,7 +56,7 @@ def ParseHeader(headerPath, parsedHeaders = set()):
 
         if PRAGMA_ONCE_MATCHER.search(headerContent) and headerPath in parsedHeaders:
             return ""
-        
+
         parsedHeaders.add(headerPath)
         headerLines = headerContent.split('\n')
 
@@ -70,7 +70,7 @@ def ParseHeader(headerPath, parsedHeaders = set()):
             if PRAGMA_ONCE_MATCHER.match(headerLine):
                 shouldSkipNextEmptyLines = True
                 continue
-        
+
             includeMatch = USER_INCLUDE_MATCHER.findall(headerLine)
             if includeMatch:
                 internalHeaderPath = os.path.abspath(os.path.join(os.path.dirname(headerPath), includeMatch[0]))
@@ -79,7 +79,7 @@ def ParseHeader(headerPath, parsedHeaders = set()):
                 outputContent += internalHeaderContent
                 shouldSkipNextEmptyLines = True
                 continue
-            
+
             includeMatch = SYSTEM_INCLUDE_MATCHER.findall(headerLine)
             if includeMatch:
                 shouldSkipNextEmptyLines = True
@@ -105,7 +105,7 @@ with open(outputHeaderPath, "w") as outputHeaderStream:
 
     outputHeaderStream.write("{}\n".format(licenseComment))
     outputHeaderStream.write("\n")
-    
+
     for systemInclude in sorted(systemIncludes):
         outputHeaderStream.write("#include <{}>\n".format(systemInclude))
     outputHeaderStream.write("\n")

untests/CMakeLists.txt

@@ -4,10 +4,10 @@ file(GLOB_RECURSE UNTESTS_SOURCES "*.cpp" "*.hpp")
 source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${UNTESTS_SOURCES})
 
 add_executable(${PROJECT_NAME} ${UNTESTS_SOURCES})
-target_link_libraries(${PROJECT_NAME} PRIVATE vmath.hpp)
+target_link_libraries(${PROJECT_NAME} PRIVATE vmath.hpp::vmath.hpp)
 
 add_executable(${PROJECT_NAME}.singles ${UNTESTS_SOURCES})
-target_link_libraries(${PROJECT_NAME}.singles PRIVATE vmath.hpp.singles)
+target_link_libraries(${PROJECT_NAME}.singles PRIVATE vmath.hpp::singles)
 
 #
 # setup defines
@@ -27,14 +27,14 @@ setup_defines_for_target(${PROJECT_NAME}.singles)
 #
 
 function(setup_libraries_for_target TARGET)
-    target_link_libraries(${TARGET} PRIVATE doctest_with_main)
+    target_link_libraries(${TARGET} PRIVATE doctest::doctest_with_main)
 
     if(${BUILD_WITH_COVERAGE})
-        target_link_libraries(${TARGET} PRIVATE enable_gcov)
+        target_link_libraries(${TARGET} PRIVATE vmath.hpp::enable_gcov)
     endif()
 
     if(${BUILD_WITH_SANITIZERS})
-        target_link_libraries(${TARGET} PRIVATE enable_asan enable_ubsan)
+        target_link_libraries(${TARGET} PRIVATE vmath.hpp::enable_asan vmath.hpp::enable_ubsan)
     endif()
 endfunction()