new build scripts

CMakeLists.txt

@@ -1,34 +1,98 @@
-# 3.8 version is required for `cxx_std_17`
-cmake_minimum_required(VERSION 3.8 FATAL_ERROR)
+cmake_minimum_required(VERSION 3.21 FATAL_ERROR)
 
-if(NOT DEFINED PROJECT_NAME)
-    set(BUILD_AS_STANDALONE ON)
-else()
-    set(BUILD_AS_STANDALONE OFF)
-endif()
+project(promise.hpp
+    VERSION "0.0.1"
+    DESCRIPTION "C++ asynchronous promises like a Promises/A+"
+    HOMEPAGE_URL "https://github.com/blackmatov/promise.hpp")
 
-project(promise.hpp)
+#
+# LIBRARY
+#
 
 add_library(${PROJECT_NAME} INTERFACE)
-target_include_directories(${PROJECT_NAME} INTERFACE headers)
-target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_17)
+add_library(promise.hpp::promise.hpp ALIAS ${PROJECT_NAME})
+
+target_compile_features(${PROJECT_NAME} INTERFACE
+    cxx_std_17)
+
+target_include_directories(${PROJECT_NAME} INTERFACE
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/headers>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
 
 find_package(Threads REQUIRED)
 target_link_libraries(${PROJECT_NAME} INTERFACE Threads::Threads)
 
-target_compile_options(${PROJECT_NAME}
-    INTERFACE
-    $<$<OR:$<CXX_COMPILER_ID:Clang>,$<CXX_COMPILER_ID:AppleClang>>:
-        -Wno-c++98-compat-pedantic
-        -Wno-ctad-maybe-unsupported
-        -Wno-padded
-        -Wno-unknown-warning-option
-        -Wno-weak-vtables>)
+#
+# INSTALL
+#
 
-if(BUILD_AS_STANDALONE)
-    option(BUILD_WITH_UNTESTS "Build with unit tests" ON)
-    if(BUILD_WITH_UNTESTS)
-        enable_testing()
-        add_subdirectory(untests)
-    endif()
+if(PROJECT_IS_TOP_LEVEL)
+    include(CMakePackageConfigHelpers)
+    include(GNUInstallDirs)
+
+    set(PROMISE_HPP_INSTALL_CONFIG_DIR
+        "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}")
+
+    set(PROMISE_HPP_INSTALL_CONFIG_INPUT
+        "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Config.cmake.in")
+
+    set(PROMISE_HPP_INSTALL_GENERATED_CONFIG_CMAKE
+        "${CMAKE_CURRENT_BINARY_DIR}/generated/${PROJECT_NAME}-config.cmake")
+
+    set(PROMISE_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE
+        "${CMAKE_CURRENT_BINARY_DIR}/generated/${PROJECT_NAME}-config-version.cmake")
+
+    configure_package_config_file(
+        "${PROMISE_HPP_INSTALL_CONFIG_INPUT}"
+        "${PROMISE_HPP_INSTALL_GENERATED_CONFIG_CMAKE}"
+        INSTALL_DESTINATION "${PROMISE_HPP_INSTALL_CONFIG_DIR}"
+        NO_SET_AND_CHECK_MACRO
+        NO_CHECK_REQUIRED_COMPONENTS_MACRO)
+
+    write_basic_package_version_file(
+        "${PROMISE_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE}"
+        VERSION ${PROJECT_VERSION}
+        COMPATIBILITY AnyNewerVersion
+        ARCH_INDEPENDENT)
+
+    install(
+        TARGETS ${PROJECT_NAME}
+        EXPORT ${PROJECT_NAME}-targets
+        INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+
+    install(
+        DIRECTORY headers/${PROJECT_NAME}
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+
+    install(
+        EXPORT ${PROJECT_NAME}-targets
+        FILE ${PROJECT_NAME}-targets.cmake
+        NAMESPACE ${PROJECT_NAME}::
+        DESTINATION "${PROMISE_HPP_INSTALL_CONFIG_DIR}")
+
+    install(
+        FILES "${PROMISE_HPP_INSTALL_GENERATED_CONFIG_CMAKE}"
+              "${PROMISE_HPP_INSTALL_GENERATED_CONFIG_VERSION_CMAKE}"
+        DESTINATION "${PROMISE_HPP_INSTALL_CONFIG_DIR}")
+endif()
+
+#
+# DEVELOPER
+#
+
+if(PROJECT_IS_TOP_LEVEL)
+    option(BUILD_WITH_COVERAGE "Build with coverage" OFF)
+    option(BUILD_WITH_SANITIZERS "Build with sanitizers" OFF)
+
+    enable_testing()
+    set_property(GLOBAL PROPERTY USE_FOLDERS ON)
+    set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMake")
+    list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
+
+    include(EnableASan)
+    include(EnableGCov)
+    include(EnableUBSan)
+
+    add_subdirectory(vendors)
+    add_subdirectory(untests)
 endif()